Codebase list gnome-shell-extensions / 057756c extensions / meson.build
057756c

Tree @057756c (Download .tar.gz)

meson.build @057756c — raw · history · blame 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
extension_schemas = []
js_sources = []

metadata_name = 'metadata.json'

foreach e : all_extensions
  uuid = e + uuid_suffix

  metadata_conf = configuration_data()
  metadata_conf.set('extension_id', e)
  metadata_conf.set('uuid', uuid)
  metadata_conf.set('gschemaname', 'org.gnome.shell.extensions.' + e)
  metadata_conf.set('gettext_domain', gettext_domain)
  metadata_conf.set('shell_current', shell_version)
  metadata_conf.set('url', 'https://gitlab.gnome.org/GNOME/gnome-shell-extensions')

  extension_sources = files(e + '/extension.js')
  extension_data = files(e + '/stylesheet.css')

  subdir(e)

  js_sources += extension_sources

  if (enabled_extensions.contains(e))
    install_data (extension_sources + extension_data,
      install_dir: join_paths(extensiondir, uuid)
    )
  endif
endforeach

install_data (extension_schemas,
  install_dir: schemadir
)

foreach js_source : js_sources
  if (js60.found())
    path_array = '@0@'.format(js_source).split('/')
    name = join_paths(path_array[-2], path_array[-1])

    test('Checking syntax of ' + name, js60,
      args: ['-s', '-c', js_source],
      workdir: meson.current_source_dir()
    )
  endif
endforeach